带有特殊字符perl的字母顺序

我有这组代码:

 use strict; 
 use warnings; 
 my %hash = ( 5328 => 'Adorable', 
              26191 => '"Giraffe"', 
              57491 => 'Is Very', 
               4915 => 'Cute',);
 foreach (sort { ($hash{$a} cmp $hash{$b}) || ($a cmp $b) } keys %hash) 
 { print "$hash{$_}\n"; }

这将导致:

"Giraffe"

Adorable

Cute

Is Very

我需要按字母顺序排序,并忽略AlphaNumeric字符之前的特殊字符,如下例所示:

Adorable

Cute

"Giraffe"

Is Very

有什么建议？

您可以这样做(请注意,我将第二个cmp更改为穿梭运算符<=>以获取数值):

foreach (sort { ($hash{$a}=~s/^\W+//r cmp $hash{$b}=~s/^\W+//r) || ($a <=> $b) } keys %hash) {
    print "$hash{$_}\n";
}

但是如果你有很多数据,最好转换你的数据(一劳永逸):例如使用schwartzian变换:

my @result = map { $_->[2] }
             sort { ($a->[0] cmp $b->[0]) || ($a->[1] <=> $b->[1]) }
             map { [ $hash{$_}=~s/^"|"$//gr, $_, $hash{$_}] } keys %hash; 

print join "\n", @result;

创建一个截断特殊字符的函数(truncate_special_chars在我的例子中).然后,在你的sort日常工作中使用它.

use strict;
use warnings;

my %hash = (
    5328 => 'Adorable',
    26191 => '"Giraffe"',
    57491 => 'Is Very',
    4915 => 'Cute',
    );


print join "\n", 
    map { $hash{$_ -> [0]} }
    sort { $a -> [1] cmp $b -> [1] || $a -> [0] <=> $b -> [0] }
    map { [ $_, truncate_special_chars($hash{$_}) ] }
    keys %hash;

sub truncate_special_chars {
    my $str = shift;
    $str =~ s/^\W//;
    # may be use lc if you want case insensitive sort
    return $str;
}

否则您可以使用,/r如果您正在使用Perl >= 5.14.