获取Windows批处理脚本(.bat)中传递的参数列表

我想找到一个与Bash相对应的Windows批处理副本,$@其中包含传递给脚本的所有参数的列表.

或者我不得不打扰shift？

1> matt wilkie..：

---

dancavallaro%*对于所有命令行参数都是正确的(不包括脚本名称本身).这些对你也可能有用:

%0-用于调用批处理文件中的命令(可以是foo,..\foo,c:\bats\foo.bat,等等)
%1是第一个命令行参数,
%2是第二个命令行参数,
并以此类推,直到%9(并且SHIFT可用于与第九之后).

%~nx0- 批处理文件的实际名称,无论调用方法(some-batch.bat)
%~dp0- 脚本的驱动器和路径(d:\ scripts)
%~dpnx0- 是脚本的完全限定路径名(d:\ scripts\some -batch.bat)

有关https://www.ss64.com/nt/syntax-args.html和https://www.robvanderwoude.com/parameters.html的更多信息示例

---

请注意,SHIFT不会影响%*,因此无法使用SHIFT [/ n]来实现从第n个参数开始访问整个命令行.

---

我发现的其他内容是`%~dpn0`将返回脚本的驱动器和路径以及批处理文件的名称,但不会返回扩展名.我发现这在创建调用具有相同名称的`.ps1`文件的批处理脚本时特别有用.基本上,`d`指的是驱动器,`p`指的是路径,`n`指的是文件的名称,`x`指的是扩展名.有了这些信息,你可以做很多事情.

---

@MatheusRocha` @ echo%~n0.my_ext`

2> dancavallaro..：

---

%* 似乎持有传递给脚本的所有参数.

3> jeb..：

---

%1... %n并%*保存参数,但访问它们可能很棘手,因为内容将被解释.
因此,用正常的陈述来处理这样的事情是不可能的

myBatch.bat "&"^&

每行都失败,因为cmd.exe尝试执行其中一个&符号(%1的内容是"&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

但是存在一个临时文件的解决方法

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

关键是要实现echo on和扩大%1一个后rem声明(也可与2%..%*).
但是为了能够重定向输出echo on,你需要两个FOR-LOOPS.

额外的字符* #用于对内容安全/?(将显示REM的帮助).
或者行末端的插入符号^可以用作多行字符.

FOR/F应该使用延迟扩展,否则内容为"!" 会被摧毁.
删除多余的字符后param1,你得到它.

并以param1安全的方式使用,启用延迟扩展.

编辑:对%0的一个评论

%0包含用于调用批处理的命令,也保留了类似的情况FoO.BaT
但是在调用函数之后%0还%~0包含函数名称(或者更好地用于调用函数的字符串).
但是%~f0你仍然可以回忆起文件名.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

产量

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

---

+++ 1 OMG - '%~f0`技巧完全出乎意料,很酷,而且可能非常有用:-)毫不奇怪,其他修饰符的工作方式相同,总是在父批处理文件上运行,即使在叫做子程序.这似乎值得它自己的问答 - "如何在被调用的子程序中访问正在运行的批处理的名称？"

4> KFL..：

---

我发现下次你需要查看这些信息时.您可以只输入call /?您的cmd,而不是打开浏览器并谷歌浏览它,您将获得它:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

5> djangofan..：

---

将所有args检索到脚本的方法如下:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

6> 小智..：

---

这是获取args并将其设置为env vars的一种相当简单的方法。在此示例中，我仅将它们称为键和值。

将以下代码示例另存为“ args.bat”。然后从命令行调用您保存的批处理文件。例如：arg.bat --x 90 --y 120

我提供了一些echo命令来逐步引导您完成此过程。但是最终结果是--x的值为90，而--y的值为120（也就是说，如果您按照上面指定的示例运行;-)）。

然后，您可以使用“如果已定义”条件语句来确定是否运行代码块。因此，我们可以说运行：“ arg.bat --x hello-world”，然后可以使用语句“ IF DEFINED --x echo％-x％”，结果将是“ hello-world”。如果运行批处理，应该更有意义。

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^ ^         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done