全局覆盖Emacs中的键绑定

如何设置全局覆盖的键绑定,并优先于该键的所有其他绑定？我想覆盖所有主要/次要模式映射,并确保我的绑定始终有效.

这当然不起作用:

(global-set-key "\C-i" 'some-function)

它起作用text-mode,但是当我使用时lisp-mode,C-i它会反弹lisp-indent-line.

我可以lisp-mode单独完成并在每个其他模式中覆盖此绑定,但必须有一个更简单的方法.每次我为新文件类型安装新模式时,我都必须返回并检查以确保所有的键绑定都没有被新模式覆盖.

我想这样做是因为我想模仿我已经学习并从其他编辑器根深蒂固的绑定.

我对所有"覆盖"键绑定使用次要模式:

(defvar my-keys-minor-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "C-i") 'some-function)
    map)
  "my-keys-minor-mode keymap.")

(define-minor-mode my-keys-minor-mode
  "A minor mode so that my key settings override annoying major modes."
  :init-value t
  :lighter " my-keys")

(my-keys-minor-mode 1)

这有一个额外的好处是能够一举关闭我的所有修改(只是禁用次要模式)以防其他人正在驾驶键盘或者我需要查看默认键绑定的作用.

请注意,您可能需要在迷你缓冲区中将其关闭:

(defun my-minibuffer-setup-hook ()
  (my-keys-minor-mode 0))

(add-hook 'minibuffer-setup-hook 'my-minibuffer-setup-hook)

作为scottfrazer答案的补充,我编写了以下内容,以便我的键绑定保留优先权,即使后续加载的库带来了他们自己的新键盘图.

因为键盘映射可以在编译时生成,所以load似乎是最好的地方.

(add-hook 'after-load-functions 'my-keys-have-priority)

(defun my-keys-have-priority (_file)
  "Try to ensure that my keybindings retain priority over other minor modes.

Called via the `after-load-functions' special hook."
  (unless (eq (caar minor-mode-map-alist) 'my-keys-minor-mode)
    (let ((mykeys (assq 'my-keys-minor-mode minor-mode-map-alist)))
      (assq-delete-all 'my-keys-minor-mode minor-mode-map-alist)
      (add-to-list 'minor-mode-map-alist mykeys))))

(require 'bind-key)
(bind-key* "C-i" 'some-function)

(add-hook 'org-mode-hook
      (lambda ()
        (local-unset-key (kbd "C-c C-b"))))