在TMemo中锁定文本的开头

我想有一个TMemo,它总是以字符串'SELECT c_name FROM'开头,我想锁定它,这样用户就无法删除或替换TMemo中的这个字符串,他们必须在这个字符串之后写下它们的文本.有人可以帮助我吗？我尝试了onChange事件,但问题是用户可以在TMemo的开头点击并在开始时进行编辑.

我正在使用Delphi 6.

您要求的是不可能的TMemo.它只是标准Win32 EDIT控件的一个薄包装器,它不支持这种功能.

你需要TRichEdit改用.它支持像您所描述的那样保护文本.添加所需文本后,使用TRichEdit.SelStart和TRichEdit.SelLength属性选择它,然后将TRichEdit.SelAttributes.Protected属性设置为true.如果用户尝试以任何方式修改受保护的文本,TRichEdit则默认情况下将拒绝修改(您可以通过使用该TRichEdit.OnProtectChange事件将AllowChange参数设置为true 来覆盖该决策).例如:

RichEdit1.Text := 'SELECT c_name FROM ';
RichEdit1.SelStart := 0;
RichEdit1.SelLength := 19;
RichEdit1.SelAttributes.Protected := True;

更新:默认情况下,保护文本也会阻止用户复制它.如果您希望用户能够复制受保护的文本,则必须明确启用它.虽然TRichEdit有一个OnProtectChange事件允许访问受保护的文本,但它不会告诉您为什么文本请求访问.但是,基础EN_PROTECTED通知确实如此.因此,您可以直接子类化TRichEdit拦截EN_PROTECTED,然后仅在用户复制受保护的文本时返回0(允许访问).

interface

uses
  ...;

type
  TMyForm = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    DefRichEditWndProc: TWndMethod;
    procedure RichEditWndProc(var Message: TMessage);
  public
    { Public declarations }
  end;

...

implementation

uses
  Richedit;

procedure TMyForm.FormCreate(Sender: TObject);
begin
  DefRichEditWndProc := RichEdit1.WindowProc;
  RichEdit1.WindowProc := RichEditWndProc;

  RichEdit1.Text := 'SELECT c_name FROM ';
  RichEdit1.SelStart := 0;
  RichEdit1.SelLength := 19;
  RichEdit1.SelAttributes.Protected := True;
end;

procedure TMyForm.RichEditWndProc(var Message: TMessage);
begin
  DefRichEditWndProc(Message);
  if Message.Msg = CN_NOTIFY then
  begin
    if TWMNotify(Message).NMHdr.code = EN_PROTECTED then
    begin
      if PENProtected(Message.lParam).Msg = WM_COPY then
        Message.Result := 0;
    end;
  end;
end;

或者:

interface

uses
  ...;

type
  TRichEdit = class(ComCtrls.TRichEdit)
  private
    procedure CNNotify(var Message: TWMNotify); message CN_NOTIFY;
  end;

  TMyForm = class(TForm)
    RichEdit1: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

...

implementation

uses
  Richedit;

procedure TMyForm.FormCreate(Sender: TObject);
begin
  RichEdit1.Text := 'SELECT c_name FROM ';
  RichEdit1.SelStart := 0;
  RichEdit1.SelLength := 19;
  RichEdit1.SelAttributes.Protected := True;
end;

procedure TRichEdit.CNNotify(var Message: TWMNotify);
begin
  inherited;
  if Message.NMHdr.code = EN_PROTECTED then
  begin
    if PENProtected(Message.NMHdr).Msg = WM_COPY then
      Message.Result := 0;
  end;
end;