如何在批处理脚本中将Windows短名称路径转换为长名称

我遇到的另一个绊脚石是确定原始路径是代表文件还是文件夹.IF EXIST "yourPath\" echo FOLDER如果路径涉及符号链接或联结,则常用的方法是附加反斜杠并使用不正确的方式将文件报告为文件夹,这在公司网络环境中很常见.

我选择使用IF EXIST "yourPath\*",发现于/sf/ask/17360801/.

但也可以使用FOR变量%%~aF属性修饰符来查找d(目录)属性,可在/sf/ask/17360801/​​8742/1012053和/sf/ask/17360801/找到1012053.

所以这是一个完全工作的纯批量解决方案

@echo off
setlocal disableDelayedExpansion

:: Validate path
set "test=%~1"
if "%test:**=%" neq "%test%" goto :err
if "%test:?=%"  neq "%test%" goto :err
if not exist "%test%"  goto :err

:: Initialize
set "returnPath="
set "sourcePath=%~f1"

:: Resolve file name, if present
if not exist "%~1\*" (
  for /f "eol=: delims=" %%F in ('dir /b "%~1"') do set "returnPath=%%~nxF"
  set "sourcePath=%~f1\.."
)

:resolvePath :: one folder at a time
for %%F in ("%sourcePath%") do (
  if "%%~nxF" equ "" (
    for %%P in ("%%~fF%returnPath%") do echo %%~P
    exit /b 0
  )
  for %%P in ("%sourcePath%\..") do (
    for /f "delims=> tokens=2" %%A in (
      'dir /ad /x "%%~fP"^|findstr /c:">          %%~nxF "'
    ) do for /f "tokens=1*" %%B in ("%%A") do set "returnPath=%%C\%returnPath%"
  ) || set "returnPath=%%~nxF\%returnPath%"
  set "sourcePath=%%~dpF."
)
goto :resolvePath

:err
>&2 echo Path not found
exit /b 1

如果有许多文件夹,用于迭代各个文件夹的GOTO将减慢操作速度.如果我真的想要优化速度,我可以使用FOR/F来调用另一个批处理过程,并在无限FOR /L %%N IN () DO...循环中解析每个文件夹,并EXIT在我到达根目录时使用它来突破循环.但我没有打扰.

Devoloping强大的实用程序,可以返回变量中的结果

有许多的优势情况下考虑到可以复杂强大的脚本开发的是^,%和!在文件/文件夹名字都是合法字符.

CALL加倍引用的^字符.除了使用变量而不是字符串文字通过引用传递值之外,这个问题没有很好的解决方案.如果输入路径仅使用短名称,则这不是问题.但如果路径使用短名称和长名称的混合,则可能是一个问题.

%在批处理参数中传递文字可能很棘手.对于谁多次(如果有的话)应该加倍,可能会让人感到困惑.同样,在变量中通过引用传递值可能更容易.

CALLer可以在FOR循环内调用该实用程序.如果变量或参数包含%,则实用程序中循环的扩展%var%或%1循环内部可能会导致无意的FOR变量扩展,因为FOR变量的范围是全局的.该实用程序不能在FOR循环中扩展参数,并且如果使用延迟扩展,则只能在FOR循环内安全地扩展变量.

!如果启用了延迟扩展,则包含FOR变量的扩展将被破坏.

CALLing环境可能启用或禁用了延迟扩展.将包含ENDLOCAL屏障!和^跨越ENDLOCAL屏障的值传递到延迟扩展环境需要将引用!转义为^!.此外,引用^必须转义为^^,但仅限于行包含!.当然,如果CALLing环境已禁用延迟扩展,则不应转义这些字符.

我已经开发了JScript和纯批处理解决方案的强大实用形式,它们考虑了上述所有边缘情况.

默认情况下,实用程序将路径视为字符串文字,但如果使用该/V选项,则接受包含路径的变量名称.

默认情况下,utilties只是将结果打印到stdout.但是如果将返回变量的名称作为额外参数传递,则结果可以在变量中返回.无论是否在CALLing环境中启用或禁用延迟扩展,都可以保证返回正确的值.

完整文档嵌入在实用程序中,可以使用该/?选项进行访问.

有一些模糊的限制:

返回变量名称不得包含!或%字符

同样,/V选项输入变量名称不得包含!或%字符.

输入路径不得包含内部双引号.路径可以用一组双引号括起来,但不应该有任何额外的引号.

我还没有测试实用程序是否在路径名中使用unicode,或者它们是否与UNC路径一起使用.

jLongPath.bat - 混合JScript /批处理

@if (@X)==(@Y) @end /* Harmless hybrid line that begins a JScript comment
:::
:::jLongPath  [/V]  SrcPath  [RtnVar]
:::jLongPath  /?
:::
:::  Determine the absolute long-name path of source path SrcPath
:::  and return the result in variable RtnVar.
:::
:::  If RtnVar is not specified, then print the result to stderr.
:::
:::  If option /V is specified, then SrcPath is a variable that
:::  contains the source path.
:::
:::  If the first argument is /?, then print this help to stdout.
:::
:::  The returned ERROLEVEL is 0 upon success, 1 if failure.
:::
:::  jLongPath.bat version 1.0 was written by Dave Benham
:::

::----------- Batch Code-----------------
@echo off
setlocal disableDelayedExpansion
if /i "%~1" equ "/?" (
  for /f "tokens=* delims=:" %%A in ('findstr "^:::" "%~f0"') do @echo(%%A
  exit /b 0
)
if /i "%~1" equ "/V" shift /1
(
  for /f "delims=* tokens=1,2" %%A in (
    'cscript //E:JScript //nologo "%~f0" %*'
  ) do if "%~2" equ "" (echo %%A) else (
    endlocal
    if "!!" equ "" (set "%~2=%%B" !) else set "%~2=%%A"
  )
) || exit /b 1
exit /b 0

------------ JScript Code---------------*/
try {
  var shortcut = WScript.CreateObject("WScript.Shell").CreateShortcut("dummy.lnk"),
      fso = new ActiveXObject("Scripting.FileSystemObject"),
      path=WScript.Arguments(0),
      folder='';
  if (path.toUpperCase()=='/V') {
    var env=WScript.CreateObject("WScript.Shell").Environment("Process");
    path=env(WScript.Arguments(1));
  }
  try {
    shortcut.TargetPath = fso.GetFile(path);
  }
  catch(e) {
    shortcut.TargetPath = fso.GetFolder(path);
    folder='\\'
  }
  var rtn = shortcut.TargetPath+folder+'*';
  WScript.StdOut.WriteLine( rtn + rtn.replace(/\^/g,'^^').replace(/!/g,'^!') );
}
catch(e) {
  WScript.StdErr.WriteLine(
    (e.number==-2146828283) ? 'Path not found' :
    (e.number==-2146828279) ? 'Missing path argument - Use jLongPath /? for help.' :
    e.message
  );
}

longPath.bat - 纯批次

:::
:::longPath  [/V]  SrcPath  [RtnVar]
:::longPath  /?
:::
:::  Determine the absolute long-name path of source path SrcPath
:::  and return the result in variable RtnVar.
:::
:::  If RtnVar is not specified, then print the result to stderr.
:::
:::  If option /V is specified, then SrcPath is a variable that
:::  contains the source path.
:::
:::  If the first argument is /?, then prints this help to stdout.
:::
:::  The returned ERROLEVEL is 0 upon success, 1 if failure.
:::
:::  longPath.bat version 1.0 was written by Dave Benham
:::
@echo off
setlocal disableDelayedExpansion

:: Load arguments
if "%~1" equ "" goto :noPath
if "%~1" equ "/?" (
  for /f "tokens=* delims=:" %%A in ('findstr "^:::" "%~f0"') do @echo(%%A
  exit /b 0
)
if /i "%~1" equ "/V" (
  setlocal enableDelayedExpansion
  if "%~2" equ "" goto :noPath
  if not defined %~2!! goto :notFound
  for /f "eol=: delims=" %%F in ("!%~2!") do (
    endlocal
    set "sourcePath=%%~fF"
    set "test=%%F"
  )
  shift /1
) else (
  set "sourcePath=%~f1"
  set "test=%~1"
)

:: Validate path
if "%test:**=%" neq "%test%" goto :notFound
if "%test:?=%"  neq "%test%" goto :notFound
if not exist "%test%" goto :notFound

:: Resolve file name, if present
set "returnPath="
if not exist "%sourcePath%\*" (
  for /f "eol=: delims=" %%F in ('dir /b "%sourcePath%"') do set "returnPath=%%~nxF"
  set "sourcePath=%sourcePath%\.."
)

:resolvePath :: one folder at a time
for /f "delims=* tokens=1,2" %%R in (^""%returnPath%"*"%sourcePath%"^") do (
  if "%%~nxS" equ "" for %%P in ("%%~fS%%~R") do (
    if "%~2" equ "" (
      echo %%~P
      exit /b 0
    )
    set "returnPath=%%~P"
    goto :return
  )
  for %%P in ("%%~S\..") do (
    for /f "delims=> tokens=2" %%A in (
      'dir /ad /x "%%~fP"^|findstr /c:">          %%~nxS "'
    ) do for /f "tokens=1*" %%B in ("%%A") do set "returnPath=%%C\%%~R"
  ) || set "returnPath=%%~nxS\%%~R"
  set "sourcePath=%%~dpS."
)
goto :resolvePath

:return
set "delayedPath=%returnPath:^=^^%"
set "delayedPath=%delayedPath:!=^!%"
for /f "delims=* tokens=1,2" %%A in ("%delayedPath%*%returnPath%") do (
  endlocal
  if "!!" equ "" (set "%~2=%%A" !) else set "%~2=%%B"
  exit /b 0
)

:noPath
>&2 echo Missing path argument - Use longPath /? for help.
exit /b 1

:notFound
>&2 echo Path not found
exit /b 1